PIZZA_SIZE_OFFSET = 0
PIZZA_PRICE_OFFSET = 12
PIZZA_STRUCT_SIZE = 16

	.text
main:
	#Locals
	# $s0 i
	# $s1 pizza_ptr
main__prologue:
	begin
	push	$ra
	push	$s0
	push	$s1			
main_body:
	li	$v0, 4
	la	$a0, menu_str			# printf("The available pizza options are:\n");
	syscall		

	li	$s0, 0				# int i = 0;
main_loop:
	bge 	$s0, 3, main_loop_end		# if ( i >= 3 ) goto main_loop_end;
  
	mul 	$t0, $s0, PIZZA_STRUCT_SIZE	# Offset: i * 16
	la	$t1, pizza_options		# Address of the array
	add	$s1, $t1, $t0			# &pizza_options[i];
	
	move	$a0, $s1			#increase_price(pizza_ptr, 100);
	li	$a1, 100
	jal 	increase_price
	
	move	$a0, $s1
	jal	print_pizza			#print_pizza_t(pizza_ptr);
    
    	addi	$s0, $s0, 1			#i = i + 1;
    	b	main_loop			# goto main_loop;
main_loop_end:

	li	$v0, 0				# return 0
main__epilogue:
	pop	$s1
	pop	$s0
	pop	$ra

	jr	$ra

########################


print_pizza:
	# Parameter $a0 -> $t0 *pizza

	move	$t0, $a0			#store input safely

	li	$v0, 4				# printf("Size: ");
	la	$a0, size_str
	syscall

	li	$v0, 4
	la	$a0, PIZZA_SIZE_OFFSET($t0)	#printf("%s", pizza->size);
	syscall

	li	$v0, 4				#     printf(", price: ");
	la	$a0, price_str
	syscall

	li	$v0, 1				#     printf("%d",pizza->price_cents);
	lw	$a0, PIZZA_PRICE_OFFSET($t0)
	syscall

	li	$v0, 4				#     printf(" cents\n");
	la	$a0, cents_str
	syscall

	jr	$ra

#########################

increase_price:
	# Parameters:
	# $a0 *pizza
	# $a1 increase_cents
	#pizza->price_cents =  pizza->price_cents + increase_cents;
	
	lw	$t0, PIZZA_PRICE_OFFSET($a0)	# pizza->price_cents
	add	$t0, $t0, $a1			# $t0 = pizza->price_cents + increase_cents;
	sw	$t0, PIZZA_PRICE_OFFSET($a0)

	jr	$ra

	.data
menu_str:
	.asciiz "The available pizza options are:\n"
size_str:
	.asciiz "Size: "
price_str:
	.asciiz ", price: "
cents_str:	
	.asciiz " cents\n"

# struct pizza_t {
#     char size[10];     //Offset 0     
#     // padding 2 bytes
#     int price_cents;   //Offset 12  
# }; //Total 16 bytes

.align 2
pizza_options:
	.asciiz "small"		#  {"small", 300},
	.space 10 - 6		#
	.space 2		#padding
	.word 300

	.asciiz "medium"	#{"medium", 550},    
	.space 3
	.space 2
	.word 550

	.asciiz "large"		#{"large", 800},    
	.space 4
	.space 2
	.word 800